Load an ephemeris of UT1-UTC.

Arguments:

InputFile filename

The name and directory of a readable UT1-UTC ephemeris file.

Example:

The following example loads a UT1-UTC ephemeris from the file ~mcs/CBI/ephem/ut1utc.ephem.

 ut1utc ~mcs/CBI/ephem/ut1utc.ephem

Context:

UTC is a time-scale with a fixed length second and occasional leap-second adjustments to keep it within a second of the time defined by the irregular rotation of the Earth. To get the latter time requires advance knowledge of the rotation rate of the Earth. Predictions based on lengthy simulations with complex models are published as bulletins by the Earth Orientation service.

To track sources precisely the control program needs to be given an ephemeris of UT1-UTC.

The format of UT1-UTC ephemeris files:

UT1-UTC ephemerides are text files containing UT1-UTC (seconds) as a function of Modified Julian Day number. The following example shows the start of the file that is in use at the time of writing. Note that Comments are introduced with the # character and extend to the end of the line.

 # CBI Ephemeris of UT1-UTC
 #
 # Note that MJD = JD - 2400000.5
 #
 # UTC (MJD)  UT1-UTC (s)  Calendar (UTC)
 #----------  -----------  --------------
 50842.00000   +0.169790   # 1998-Jan-29
 50843.00000   +0.167580   # 1998-Jan-30
 50844.00000   +0.165260   # 1998-Jan-31
 50845.00000   +0.162890   # 1998-Feb-01
 50846.00000   +0.160560   # 1998-Feb-02
 50847.00000   +0.158320   # 1998-Feb-03

The current ephemeris was produced by visiting:

 ftp://maia.usno.navy.mil/ser7/ser7.dat

with Netscape, using cut and paste to copy the body of the primary table to a text file, then applying the following awk script to the result.

 #!/bin/awk -f

 BEGIN {

 # When the expected column headings of the table have been seen, in_table
 # will be set to 1.

   in_table = 0

 # Create a lookup table of 3-letter month names.

   split("Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec", months)
 }

 # In the current bulletin there are four column headings. The first
 # three columns don't have names. Once these headings have been seen
 # the file header has passed and the table of data should start.

 $1=="MJD" && $2=="x(arcsec)" && $3=="y(arcsec)" && $4=="UT1-UTC(sec)" {
   in_table = 1;

 # Describe the contents of the ut1-utc ephemeris that is being produced.

   printf("# CBI Ephemeris of UT1-UTC\n");
   printf("#\n");
   printf("# Note that MJD = JD - 2400000.5\n");
   printf("#\n");
   printf("# UTC (MJD)  UT1-UTC (s)  Calendar (UTC)\n");
   printf("#----------  -----------  --------------\n");

 }

 # The current bulletin has 7 columns, which are:
 #  year, month(1-12), day(1-31), MJD x(arcsec) y(arcsec) UT1-UTC(sec).

 in_table!=0 && NF==7 && $1 ~ /^(19|20)[0-9][0-9]/ {
   year = $1;
   month = months[$2];
   day = $3;
   mjd = $4;
   ut1utc = $7;
   printf("%.5f  %+10.6f   # %s-%s-%02d\n", mjd, ut1utc, year, month, day);
 }